# Author: Ika
# Date: 12/31/2014

set term svg font 'Times, 18' size 1000,1000
set output 'affine_conn_eg.svg'

set size ratio 1
set xrange [-1.5:1.5]
set yrange [-1.5:1.5]
# Unit along the axes
set xtics 1
set ytics 1
unset grid

unset label
set key off

# The following block shows the red vector field.
# j stands for a different radius r
do for [j=1:25] {
r = 2/25.0*j
# i stands for a different angle \theta
do for [i=1:50] {
theta = 2*pi/50.0*(i-1)
set arrow j*50+i from r*cos(theta), r*sin(theta) to r*(cos(theta)-0.5*sin(theta)), r*(sin(theta)+0.5*cos(theta)) lw 1 lc rgb "red"
}
}

# The following block shows the blue vector field.
# j stands for a different radius r
do for [j=1:10] {
r = 2/10.0*j
# i stands for a different angle \theta
do for [i=1:50] {
theta = 2*pi/50.0*(i-1)
set arrow j*50+i+2000 from r*cos(theta), r*sin(theta) to (r+0.1)*cos(theta), (r+0.1)*sin(theta) lw 1 lc rgb "blue"
}
}

# To show the arrows, I have to plot something. So I choose a trivial zero function.
set parametric
plot 0,0 lw 1 lc rgb "rgb"

set term x11
set output