a = 1;
\[Omega] =(*0.9/(a 2 \[Pi])*)0.05
rsed[t_] := {0, a Sin[2 \[Pi] \[Omega] t], 0}; (*position of the source*)
c = 1; (*speed of light*)
\[Beta]ed[t_] := Evaluate@D[rsed[t1], t1] /. t1 -> t;
d\[Beta]ed[t_] := Evaluate@D[\[Beta]ed[t1], t1] /. t1 -> t;
\[Gamma]ed[t_] := 1/Sqrt[1 - Norm[\[Beta]ed[t]]^2];
ned[r_, t_] := (r - rsed[t])/Norm[r - rsed[t]];
tred[r_, t_] := t - Norm[r - rsed[t]]/c;
Efed[q_, r_, t_] := (q (ned[r, t] - \[Beta]ed[t])/(\[Gamma]ed[t]^2 (1 - ned[r, t].\[Beta]ed[t])^3 Norm[r - rsed[t]]^2) + q ned[r, t] \[Cross]((ned[r, t] - \[Beta]ed[t])\[Cross]d\[Beta]ed[t])/(c (1 - ned[r, t].\[Beta]ed[t])^3 Norm[r - rsed[t]]) )
Bfed[q_, r_, t_] := (q (c (\[Beta]ed[t]\[Cross]ned[r, t]))/(\[Gamma]ed[t]^2 (1 - ned[r, t].\[Beta]ed[t])^3 Norm[r - rsed[t]]^2) + q ned[r, t] \[Cross](ned[r, t]\[Cross]((ned[r, t] - \[Beta]ed[t])\[Cross]d\[Beta]ed[t]))/((1 - ned[r, t].\[Beta]ed[t])^3 Norm[r - rsed[t]]) )
Sed[q_, r_, t_] := Efed[q, r, t]\[Cross]Bfed[q, r, t]
\[Tau] =.
p1 = Table[
  DensityPlot[Norm[Sed[1, {x, y, 0}, tred[{x, y, 0}, \[Tau]]] + Sed[-1, {x, y, 0}, tred[{x, y, 0}, \[Tau] + 1/(2 \[Omega])]] ] , {x, -30, 30}, {y, -30, 30}, ColorFunction -> "AvocadoColors", 
   PlotRange -> {0, 0.0005}, AspectRatio -> 1, PlotPoints -> 100, Frame -> False, Epilog -> {Black, Disk[rsed[\[Tau]][[1 ;; 2]], 0.5 ], Disk[rsed[\[Tau] + 1/(2 \[Omega])][[1 ;; 2]], 0.5]}, PlotLabel -> "Electrc dipole, |S|", LabelStyle -> {Black, Bold}], {\[Tau], 0, 1/\[Omega], 1/(\[Omega] 20)}]
ListAnimate[p1, 10]

Yo, el titular de los derechos de autor de esta obra, la publico en los términos de la siguiente licencia:

Este archivo está disponible bajo la licencia Dedicación de Dominio Público CC0 1.0 Dedicación a Dominio Público Universal de Creative Commons.

La persona que ha asociado una obra a este documento lo dedica al dominio público mediante la cesión mundial de sus derechos bajo la ley de derechos de autor y todos los derechos legales adyacentes propios de dicha, en el ámbito permitido por ley. Puedes copiar, modificar, distribuir y reproducir el trabajo, incluso con objetivos comerciales, sin pedir aprobación del autor. http://creativecommons.org/publicdomain/zero/1.0/deed.enCC0Creative Commons Zero, Public Domain Dedicationfalsefalse

Este archivo, el cual fue publicado originalmente en https://twitter.com/j_bertolotti/status/1030470604418428929, fue revisado el 17 December 2018 por el revisor Ronhjones, quien confirmó que en esa fecha estaba disponible bajo la licencia indicada.