Archivo:Moving coil instrument principle.png

Resumen

DescripciónMoving coil instrument principle.png	English: Technical realisation of a moving coil instrument. Legend for numbers in the illustration: 1) Core for moving coil, 2) Permanent magnet, 3) Pole "shoe" for focusing magnetic field, 4) Dial, 5) Aiming mirror on dial, 6) Coil spring, 7) Coil, 8) Coil at rest, 9) Coil at full deflection, 10) Coil yoke, 11) intentionally left out, 12) Pointer, 13) Pointer at rest, 14) Pointer at full deflection. Rendered using POV-Ray (see http://www.povray.org/). Deutsch: Technische Ausführung eines Drehspulinstruments. Legende: 1) Weicheisenkern der Drehspule, 2) Permanentmagnet, 3) Polschuh zur Bündelung des Magnetfeldes, 4) Skala, 5) Hilfsspiegel zur genauen Ablesung, 6) Rückstellfeder, 7) Drehspule, 8) Drehspule in Nulllage, 9) Drehspule bei Maximalausschlag, 10) Joch der Spule, 11) (fehlt), 12) Zeiger, 13) Zeiger in Nulllage, 14) Zeiger bei Maximalausschlag. Das Bild wurde mit POV-Ray erzeugt (see http://www.povray.org/).
Fecha	24 de junio de 2005
Fuente	Self made with POV-Ray. See source code below.
Autor	Søren Peo Pedersen (User:Peo) Reworked version Dr. Schorsch (discusión) 08:43, 6 November 2018 (UTC)

Licencia

Yo, el titular de los derechos de autor de esta obra, la publico en los términos de la siguiente licencia:

Se autoriza la copia, distribución y modificación de este documento bajo los términos de la licencia de documentación libre GNU, versión 1.2 o cualquier otra que posteriormente publique la Fundación para el Software Libre; sin secciones invariables, textos de portada, ni textos de contraportada. Se incluye una copia de la dicha licencia en la sección titulada Licencia de Documentación Libre GNU.

	Este archivo se encuentra bajo la licencia Creative Commons Genérica de Atribución/Compartir-Igual 3.0.

	Eres libre: de compartir – de copiar, distribuir y transmitir el trabajo de remezclar – de adaptar el trabajo Bajo las siguientes condiciones: atribución – Debes otorgar el crédito correspondiente, proporcionar un enlace a la licencia e indicar si realizaste algún cambio. Puedes hacerlo de cualquier manera razonable pero no de manera que sugiera que el licenciante te respalda a ti o al uso que hagas del trabajo. compartir igual – En caso de mezclar, transformar o modificar este trabajo, deberás distribuir el trabajo resultante bajo la misma licencia o una compatible como el original.
	Esta etiqueta de licencia fue agregada a este archivo como parte de la actualización de la licencia GFDL.CC BY-SA 3.0truetrue

Pov-Ray Source code

The scene description code below supports rendering both of the two sections in this illustration using the free software Povray; the overall view at the top, and the close-up below. The two sections were subsequently combined, and the numbers added, in a graphics software package.

Display source code

 /*
 =======================================================
 Demonstrating the principle of a moving coil instrument
 -------------------------------------------------------
 Created by Søren Peo Pedersen - see my user page at
 http://da.wikipedia.org/wiki/Bruger:Peo
 =======================================================
 */
 
 #declare CloseUp=yes;
 #declare Fontname="arialbd.ttf";
 
 
 global_settings {max_trace_level 256}
 
 #local txtMetal=texture {
   pigment {color rgb .5}
   finish {
       metallic
       phong 1
       reflection .5
       }
   }
 
 #include "functions.inc"
 #local CoilSpring=isosurface {function {f_spiral(-x,z/5,y,.2,.01,1.34,0,0,0)}
     contained_by { box {<-2,-2,-.2>,<2,2,.2>} }  // container shape
     accuracy 0.001                      // accuracy of calculation [0.001]
     max_gradient 4                      // maximum gradient the function can have [1.1]
     texture {txtMetal}
     }
 
 #macro txtCoilYoke(Transparency)
     texture {pigment {color rgbt <.5,1,0,Transparency>} finish {ambient .4}}
 #end
 
 #macro MovingPart(Transparency)
   #local txtCopper=texture {  // Texture for copper wire in coil
     pigment {color 
       #if (Transparency=0)
         rgb <.5,.25,.15>
       #else
         rgbt <1,.5,.3,Transparency>
       #end
       }
     finish {            
       #if (Transparency=0)
         metallic 1
         reflection rgb <1,.5,.3> 
         phong 1
         ambient .4
       #end
       }
     }
   
   #local FramePart=merge {  // One of four "sides" in the square-shaped coil
     difference {  // Staright parts of coil yoke
       box {<-.3,1,-1.00001>,<.3,1.5,1.00001>}
       box {<-.25,1.05,-2>,<.25,2,2>}
       txtCoilYoke(Transparency)
       }
     difference {  // Rounded corners of coil yoke
       cylinder {<-.3,1,-1>,<.3,1,-1>,.5}
       box {<-.25,0,-2>,<.25,2,0>}
       box {<-1,1,-2>,<1,2,-1> inverse}
       txtCoilYoke(Transparency)
       }
     
     #local n=0; // Outermost layer of windings on coil
     #while (n<11)
         cylinder {<-.275+.05*n,1.4,-1.00001>,<-.275+.05*n,1.4,1.00001>,.025 texture {txtCopper}}
         intersection {
             torus {.4,.025}
             box {<0,-1,-1>,<1,1,0>}
             rotate <0,0,90>
             translate <-.275+.05*n,1,-1>
             texture {txtCopper}
             }
         #local n=n+1;
     #end
     
     #local n=0;
     #while (n<7)
       cylinder {<.225,1.35-.05*n,-1.00001>,<.225,1.35-.05*n,1.00001>,.025 texture {txtCopper}}
       intersection {
         torus {.35-.05*n,.025}
         box {<0,-1,-1>,<1,1,0>}
         rotate <0,0,90>
         translate <.225,1,-1>
         texture {txtCopper}
         }
       #local n=n+1;
     #end
     
     }
   
   #merge {  // The entire mobile coil on its yoke:
       #object {FramePart}
       #object {FramePart rotate <90,0,0>}
       #object {FramePart rotate <180,0,0>}
       #object {FramePart rotate <270,0,0>}        
       box {<-.03,0,-1.79>,<.03,5,-1.81> // Needle
         pigment {color rgbt <0,0,0,Transparency>}
   // Changed by user:xorx due to this comment
         rotate <0,0,-90>
         }
       }
 #end
 
 #declare MagnetPoleShoe=merge {
   cylinder {<-1.44222,-.9,-.8>,<-1.44222,-.9,.8>,.1}
   cylinder {<-1.44222, .9,-.8>,<-1.44222, .9,.8>,.1}
   sphere {<-1.44222,-.9,-.8>,.1}
   sphere {<-1.44222, .9,-.8>,.1}
   sphere {<-1.44222,-.9, .8>,.1}
   sphere {<-1.44222, .9, .8>,.1}
   cylinder {<-1.44222,-.9,-.8>,<-1.8,-.9,-.8>,.1}
   cylinder {<-1.44222,-.9, .8>,<-1.8,-.9, .8>,.1}
   cylinder {<-1.44222, .9,-.8>,<-1.8, .9,-.8>,.1}
   cylinder {<-1.44222, .9, .8>,<-1.8, .9, .8>,.1}
   box {<-1.8,.9,-.8>,<-1.44222,1,.8>}
   box {<-1.8,-1,-.8>,<-1.44222,-.9,.8>}
   difference {
     box {<-1.8,-.9,-.9>,<0,.9,.9>}
     cylinder {<0,0,-5>,<0,0,5>,1.7}
     }
   difference {
     box {<-1.799999,-.837596,-.8>,<0,.837596,.8>}
     cylinder {<0,0,-5>,<0,0,5>,1.6}
     }
   difference {
     merge {
       torus {1.7,.1 rotate <90,0,0> translate <0,0,-.8>}
       torus {1.7,.1 rotate <90,0,0> translate <0,0,.8>}
       }
     plane {<0,1,0>,0 rotate <0,0,31.9657>}
     plane {<0,-1,0>,0 rotate <0,0,-31.9657>}
     }
   texture {txtMetal}
   }
 
 #object {MagnetPoleShoe}
 #object {MagnetPoleShoe scale <-1,1,1>}
 
 #if (CloseUp)
   // Changed by user:xorx due to this comment
   #object{MovingPart(0) translate <0,0,-.000001> rotate <0,0,135>}
   #object {MovingPart(.7) rotate <0,0,45>}
 #else
   #object{MovingPart(0) rotate <0,0,100>}
 #end
 
 cylinder {<0,0,-2>,<0,0,-1.5>,.4 txtCoilYoke(0)}
 cylinder {<0,0,1.5>,<0,0,1.7>,.4 txtCoilYoke(0)}
 cylinder {<0,0,-2.5>,<0,0,-2>,.1 texture {txtMetal}}
 cylinder {<0,0,1.7>,<0,0,2.2>,.1 texture {txtMetal}}
 
 #object {CoilSpring translate <0,0,1.6>}
 #object {CoilSpring translate <0,0,-1.6>}
 
 merge { // Core inside moving coil
     cylinder {<0,0,-.9>,<0,0,.9>,.8}
     cylinder {<0,0,-.8>,<0,0,.8>,.9}
     torus {.8,.1 rotate <90,0,0> translate <0,0,-.8>}
     torus {.8,.1 rotate <90,0,0> translate <0,0,.8>}
     texture {txtMetal}
     }
 
 merge { // Frame & screw for mechanical adjustment
   difference {
     box {<-.2,-2,-2.8>,<.2,.2,2.5>}
     box {<-1,-1.25,-2.2>,<1,1,1.9>}
     box {<-1,-1.6,-1.5>,<1,1,1.5>}
     }
   cylinder {<0,0,-2.8>,<0,0,-3.3>,.2}
   difference {
     cylinder {<0,0,-3.3>,<0,0,-4>,.4}
     sphere {<0,0,-2>,1.6 inverse}
     box {<-1,-.1,-5>,<1,.1,-3.4>}
     }
   pigment {color rgb <0,.5,1>}
   finish {ambient .4}
   }
   
 difference {  // Horse-shoe permanent magnet
   merge {
     box {<-3.8,-1,-1>,<3.8,3,1>}
     cylinder {<0,3,-1.000001>,<0,3,1.000001>,3.8}
     }
   box {<-1.8,-2,-2>,<1.8,3,2>}
   cylinder {<0,3,-2>,<0,3,2>,1.8}
   pigment {
     object {
       union {
         text {ttf Fontname,"S",1,0 scale 3.1 translate <-3.7,-.85,-1.5>}
         difference {
           plane {<-1,0,0>,0}
           text {ttf Fontname,"N",1,0 scale 3.1 translate <1.9,-.85,-1.5>}
           }        
         }
       color rgb 1
       color rgb <1,0,0>
       }
     }
   finish {ambient .4}
   }   
 
 box {<-4.3,3,-1.7>,<4.3,6,-1.68>  // Scale behind needle:
   pigment {
     object {
       union {
         #local n=0;
         #while (n<101)
           #local h=5.1;
           #if (n/5=int(n/5)) #local h=5.2; #end
           #if (n/10=int(n/10))
             #local h=5.3;
             #local Number=text {ttf Fontname,str(n/10,0,0),.04,0 scale .5}
             #object {
               Number
               translate <(min_extent(Number).x-max_extent(Number).x)/2,5.35,-1.71>
               rotate <0,0,45-.9*n>
               }
           #end
           box {
             <-.01,4.8,-1.71>,<.01,h,-1.69>
             rotate <0,0,45-.9*n>
             }
           #local n=n+1;
         #end
         }
       color rgbt <1,1,1,.5>
       color rgbt <0,0,0,.5>
       }
     }
   finish {ambient .4}
   }
 
 difference {
   cylinder {<0,0,-1.7002>,<0,0,-1.7001>,4.75}
   cylinder {<0,0,-2>,<0,0,-1>,4.55}
   box {<0,0,-2>,<9,9,-1> inverse rotate <0,0,45>}
   pigment {color rgb 0}
   finish {reflection .95}
   }
 
 #declare Spotty=pigment {
   bozo
   color_map {
     [0 color rgb .5]
     [1 color rgb 1]
     }
   scale .05
   }
   
 sky_sphere {
   pigment {
     gradient z
     pigment_map {
       [0 Spotty]
       [.8 Spotty]
       [.913 color rgb <1,1,1>]
       [1 color rgb <1,1,1>]
       }
     scale 2
     translate <0,0,-1>
     rotate <15.5,28.5,0>
     }
   }
 
 camera {
   up <0,1,0> right <.93,0,0>
   location <-5,5,-9>
   #if (CloseUp)
     look_at <0,-.45,-.8> angle 24
   #else
     look_at <-.55,2.4,-.8>
   #end
   }
 
 light_source {<50,150,100> color rgb 1}
 light_source {<-100,80,-150> color rgb 1}

Archivo:Moving coil instrument principle.png

Resumen

Licencia

Pov-Ray Source code

Leyendas

Elementos representados en este archivo

representa a

instrumento de bobina móvil

estatus de los derechos de autor

bajo derechos de autor

licencia

Licencia de documentación libre de GNU, versión 1.2 o posterior

Creative Commons Atribución-CompartirIgual 3.0 No portada

fecha de fundación o creación

24 jun 2005

Historial del archivo

Usos del archivo

Menú de navegación

Archivo:Moving coil instrument principle.png

Resumen

Licencia

Pov-Ray Source code

Leyendas

Elementos representados en este archivo

24 jun 2005

Historial del archivo

Usos del archivo

Menú de navegación

Buscar